Tylko cyfry w InputQuery

Cześć, jak zrobić, żeby w edicie w inputQuery można było wpisywać tylko cyfry?

np napisac wlasnego korzystajac ze zrodla standardowego z modułu Dialogs
i zamiast Edit dac np MaskEdit z ustawioną maską tylko na liczby lub np. NumberEdit z JVCL

function InputQuery(const ACaption, APrompt: string;
  var Value: string): Boolean;
var
  Form: TForm;
  Prompt: TLabel;
  Edit: TEdit;
  DialogUnits: TPoint;
  ButtonTop, ButtonWidth, ButtonHeight: Integer;
begin
  Result := False;
  Form := TForm.Create(Application);
  with Form do
    try
      Canvas.Font := Font;
      DialogUnits := GetAveCharSize(Canvas);
      BorderStyle := bsDialog;
      Caption := ACaption;
      ClientWidth := MulDiv(180, DialogUnits.X, 4);
      Position := poScreenCenter;
      Prompt := TLabel.Create(Form);
      with Prompt do
      begin
        Parent := Form;
        Caption := APrompt;
        Left := MulDiv(8, DialogUnits.X, 4);
        Top := MulDiv(8, DialogUnits.Y, 8);
        Constraints.MaxWidth := MulDiv(164, DialogUnits.X, 4);
        WordWrap := True;
      end;
      Edit := TEdit.Create(Form);
      with Edit do
      begin
        Parent := Form;
        Left := Prompt.Left;
        Top := Prompt.Top + Prompt.Height + 5;
        Width := MulDiv(164, DialogUnits.X, 4);
        MaxLength := 255;
        Text := Value;
        SelectAll;
      end;
      ButtonTop := Edit.Top + Edit.Height + 15;
      ButtonWidth := MulDiv(50, DialogUnits.X, 4);
      ButtonHeight := MulDiv(14, DialogUnits.Y, 8);
      with TButton.Create(Form) do
      begin
        Parent := Form;
        Caption := SMsgDlgOK;
        ModalResult := mrOk;
        Default := True;
        SetBounds(MulDiv(38, DialogUnits.X, 4), ButtonTop, ButtonWidth,
          ButtonHeight);
      end;
      with TButton.Create(Form) do
      begin
        Parent := Form;
        Caption := SMsgDlgCancel;
        ModalResult := mrCancel;
        Cancel := True;
        SetBounds(MulDiv(92, DialogUnits.X, 4), Edit.Top + Edit.Height + 15,
          ButtonWidth, ButtonHeight);
        Form.ClientHeight := Top + Height + 13;          
      end;
      if ShowModal = mrOk then
      begin
        Value := Edit.Text;
        Result := True;
      end;
    finally
      Form.Free;
    end;
end;

w zdarzeniu OnKeyPress komponentu dodaj:

begin
  if not (key in ['0'..'9',#8{backspace},#9{tab}]) then 
  begin
    Key := #0;
    MessageBeep(0);
  end;
end;

@Sean77 a może InputQuery nie jest komponentem? A po drugie to niezłe wykopalisko ledwie 6 lat :)

Jeżeli nie chce się robić własnego InputQuery można znaleźć uchwyt TForm okna InputQuery a później znajdującej się w nim kontrolki TEdit i zmienić jej styl dodając ES_NUMBER.
Można to zrobić np. w ten sposób:

function TForm1.InputQueryEx(const ACaption, APrompt: string;
       var Value: string): Boolean;
begin
  Timer1.Interval:= 100;
  Timer1.Enabled:= True;
  result:= InputQuery(ACaption, APrompt, Value);
end;

procedure TForm1.Timer1Timer(Sender: TObject);
var
  i, iStyle: Integer;
  hWnd: THandle;
begin
  for i:= 0 to Screen.FormCount - 1 do
  begin
    if (Screen.Forms[i].Name = '') then  //to jest InputQuery
    begin
      hWnd:= Screen.Forms[i].Handle;
      hWnd:= FindWindowEx(hWnd, 0, 'TEdit', nil); //uchwyt Edit
      if hWnd <> 0 then
      begin
        iStyle:= GetWindowLong(hWnd, GWL_STYLE); //pobieramy styl EDit
        iStyle:= iStyle or ES_NUMBER; //dodajemy ES_NUMBER (ten styl pozwala wpisywac tylko cyfry)
        SetWindowLong(hWnd, GWL_STYLE, iStyle); //zmiana stylu na nowy
        Timer1.Enabled:= False;
        break;
      end;
    end;
  end;
end;

Ja użyłem Timera i w jego zdarzeniu OnTimer szukam uchwytu zamiast Timera można by utworzyć wątek i w nim szukać.

PS: Zamiast GetWindowLong i SetWindowLong dla kompatybilności z x64 lepiej użyć nowszych ich odpowiedników czyli GetWindowLongPtr i SetWindowLongPtr ale ja pisałem w Delphi 7 gdzie nie ma ich zadeklarowanych a dla przykładu specjalnie deklarować mi się nie chciało.