Kontakty MS Outlook

kiedys na forum bylo podobne pytanie - odpofiedz tyczyla sie rejestrow.... jednakze niezbyt dokladnie

jak pobrac do pliki adresy e-mail z ksiazki adresowej i zapisac je do pliku

i jeszcze takie pytanko mam winxp i na podstawie artu o rejestrach nie tworzy ani nie ort! zadnych kluczy - dlaczego ?

//jezeli nie znasz odp na pyt 1 to nie odpowiadaj na drugie :P

ELO

jak pobrac do pliki adresy e-mail z ksiazki adresowej i zapisac je do pliku

hmmm.... coś mylisz te dwa programy, książka adresowa Windowsa jest
wykorzystywana w Outlook Express i wyciągnięcie z niej
adresów jest proste...

Natomiast kontakty w Microsoft Outlooku to już inna sprawa,
plik z adresami jest zaszyfrowany, nie wiem jak, może coś w googlach znajdziesz...

Można wyciągnąć adresy po przez objekt automatyzacji
ale wtedy wyświetla się komunikat o tym że jakiś
program chce odczytać kontakty, i czy się na to zgadzasz,
więc jeśli piszesz wirusa to zapomnij...

Napisz co Cię interesuje to udzielę więcej informacji...

dokladnie to chodzi mi o wyciagniecie kontaktow z
c:\Program Files\Outlook Express\wab.exe
kiedys bylo o tym na forum ze wyciagnac da sie to z rejestru
HKEY_CURRENT_USER\Software\Microsoft\WAB\WAB4\Wab File Name
ale na tym sie skonczylo i po prostu nefem co dalej (przeczytalem arty o rejestrach, jednakze na winXP jakos mi ne dziala to co jest tam opisane)
//nie pisze wirusa hheh po prostu chcialem to sobie wyjasnic ;-)

Lubie takie tematy, można sobie pokodzić :-D
przykład działa u mnie pod XP...

program Emails;

uses Windows;

function RegRS(kRoot: HKEY; sKey, sValue: String): String;
var
  qValue: Array[0..1023] of Char;
  DataSize: Integer;
  CurrentKey: HKEY;
begin
  Result := '';
  RegOpenKeyEx(kRoot,PChar(sKey),0,KEY_ALL_ACCESS,CurrentKey);
  Datasize := 1023;
  if ERROR_SUCCESS = RegQueryValueEx(CurrentKey,PChar(sValue),
    nil,nil,@qValue[0],@DataSize) then Result := String(qValue);
  RegCloseKey(CurrentKey);
end;

function ReadWab(FName: String): String;
  function Ws2s(s: String): String;
  var
    i : Integer;
  begin
    Result := '';
    for i := 1 to Length(s) do 
      if s[i] <> #0 then Result := Result + s[i];
  end;
  function isEml(s: String): Boolean;
  begin
    Result := (Length(s) > 6) and 
      (Pos('@',s) > 1) and (Pos('.',s) > 0);
  end;
var
  F : File of Byte;
  Str, Eml : String;
  i : Integer;
begin
  Result := '';
  AssignFile(F,FName);
  FileMode := 0;
  Reset(F);
  try
    SetLength(Str,FileSize(F));
    BlockRead(F,Str[1],Length(Str));
  finally
    CloseFile(F);
  end;
  i := Pos(#3#48,Str);
  while i > 0 do begin
    Delete(Str,1,i + 1);
    if Copy(Str,2,3) = #0#0#0 then begin
      Eml := Ws2s(Copy(Str,4,Ord(Str[1])));
      if isEml(Eml) then
        Result := Result + Eml + #13#10;
    end;
    i := Pos(#3#48,Str);
  end;
  Delete(Result,Length(Result) - 1,2);
end;

var
  Wab : String;
begin
  Wab := RegRS(HKEY_CURRENT_USER,'software\microsoft\wab\wab4\wab file name','');
  MessageBox(0,PChar(ReadWab(Wab)),'Emails',0);
end.

Lubie takie tematy, można sobie pokodzić :-D

hheh ne bardzo cie czaje ale looz
ogolem wielkie dzieki za ta odpowiedz - pozdro

PEACE /http://www.ugly.people.prv.pl

Hmm...no super piechnat, u mnie też to zadziałało, ale jeśli chciałoby się wyciagnąc z waba wszytsko a nie tylko adresy e-mail?