Jak wygenerować dźwięk o określonej częstotliwości

do uses dodaj:  
MMSystem  

A w implementation :

type
 TVolumeLevel = 0..127;
 
procedure MakeSound(Frequency{Hz}, Duration{mSec}: Integer; Volume: TVolumeLevel);
var
  WaveFormatEx: TWaveFormatEx;
  MS: TMemoryStream;
  i, TempInt, DataCount, RiffCount: integer;
  SoundValue: byte;
  w: double; // omega ( 2 * pi * frequency)
const
  Mono: Word = $0001;
  SampleRate: Integer = 11025; // 8000, 11025, 22050, or 44100
  RiffId: string = 'RIFF';
  WaveId: string = 'WAVE';
  FmtId: string = 'fmt ';
  DataId: string = 'data';
begin
  if Frequency > (0.6 * SampleRate) then
  begin
    ShowMessage(Format('Sample rate of %d is too Low to play a tone of %dHz',
      [SampleRate, Frequency]));
    Exit;
  end;
  with WaveFormatEx do
  begin
    wFormatTag := WAVE_FORMAT_PCM;
    nChannels := Mono;
    nSamplesPerSec := SampleRate;
    wBitsPerSample := $0008;
    nBlockAlign := (nChannels * wBitsPerSample) div 8;
    nAvgBytesPerSec := nSamplesPerSec * nBlockAlign;
    cbSize := 0;
  end;
  MS := TMemoryStream.Create;
  with MS do
  begin
    {Calculate length of sound data and of file data}
    DataCount := (Duration * SampleRate) div 1000; // sound data
    RiffCount := Length(WaveId) + Length(FmtId) + SizeOf(DWORD) +
      SizeOf(TWaveFormatEx) + Length(DataId) + SizeOf(DWORD) + DataCount; // file data
    {write out the wave header}
    Write(RiffId[1], 4); // 'RIFF'
    Write(RiffCount, SizeOf(DWORD)); // file data size
    Write(WaveId[1], Length(WaveId)); // 'WAVE'
    Write(FmtId[1], Length(FmtId)); // 'fmt '
    TempInt := SizeOf(TWaveFormatEx);
    Write(TempInt, SizeOf(DWORD)); // TWaveFormat data size
    Write(WaveFormatEx, SizeOf(TWaveFormatEx)); // WaveFormatEx record 
    Write(DataId[1], Length(DataId)); // 'data' 
    Write(DataCount, SizeOf(DWORD)); // sound data size 
    {calculate and write out the tone signal} // now the data values 
    w := 2 * Pi * Frequency; // omega 
    for i := 0 to DataCount - 1 do
    begin 
      SoundValue := 127 + trunc(Volume * sin(i * w / SampleRate)); // wt = w * i / SampleRate 
      Write(SoundValue, SizeOf(Byte)); 
    end; 
    {now play the sound} 
    sndPlaySound(MS.Memory, SND_MEMORY or SND_SYNC); 
    MS.Free; 
  end;
end;
 
No i przykład wykorzystania :
 
procedure TForm1.Button1Click(Sender: TObject);
begin
 MakeSound(261, 500, 60);  (częstotliwość,czas trwania, głośność)
 MakeSound(293, 500, 60);
 MakeSound(329, 500, 60);
 MakeSound(349, 500, 60);
 MakeSound(392, 500, 60);
 MakeSound(440, 500, 60);
 MakeSound(493, 500, 60);
 MakeSound(523, 500, 60)
end;

Kategoria: Delphi » Multimedia

7 komentarzy

Avatar: Legalnl
Napisany 2010-09-01 15:37 przez Legalnl

nie no artykuł fajny ;) A Sound() i delay () nie dawało takiego ładnego dzwięku :D

Avatar: bordeux
Napisany 2008-01-23 10:35 przez bordeux

UnAdamBoduch: Z jakiej??? Sprawdź czy ten autor twojego plagiatu nie przypadkiem ten co pisał tego arta :p parę razy sie to zdarzało :p
khajiit: dodałęs do uses MMSystem  ??

Brak avatara
Napisany 2008-01-25 20:35 przez mrgiver

gdzie te czasy, że kombinacja sound(), delay(), nosound wystarczała i zadowalała ... ale artykuł potrzebny, nie powiem

Brak avatara
Napisany 2005-09-21 09:48 przez UnAdamBoduch

<b><u>Plagiat</u> - kod pochodzi z innej strony</b> [!!!]

Brak avatara
Napisany 2004-08-25 20:37 przez khajiit

wyskakuje mi następujący błąd: "[Error] Unit1.pas(26): Undeclared identifier: 'TVolumeLevel'". Co jest nie tak?

Brak avatara
Napisany 2004-01-01 23:56 przez blokers

A jest cos krotszego co dalo by taki sam efekt??

Avatar: Drajwer
Napisany 2003-03-12 19:00 przez Drajwer

fajne

Facebook
4programmers.net