Jak wyświetlić z poziomu kodu okno "Właściwości pl

Odpowiedz Nowy wątek
2006-07-24 14:56
Ad
0

Jak wyświetlić z poziomu kodu okno "Właściwości pliku" takie jak po kliknięciu PPM w Eksploratorze "Właściwości".
czyli:user image


Pozostało 580 znaków

2006-07-24 19:37
Opi
0

Przykład poprawnie funkcjonuje dla Windows 2000 i nowszym

uses ActiveX, ShlObj, ComObj;
 
function SHMultiFileProperties(pDataObj: IDataObject; Flag: DWORD): HRESULT;
  stdcall; external 'shell32.dll';
 
function GetFileListDataObject(Files: TStrings): IDataObject;
type
  PArrayOfPItemIDList = ^TArrayOfPItemIDList;
  TArrayOfPItemIDList = array[0..0] of PItemIDList;
var
  Malloc: IMalloc;
  Root: IShellFolder;
  p: PArrayOfPItemIDList;
  chEaten, dwAttributes: ULONG;
  i, FileCount: Integer;
begin
  Result := nil;
  FileCount := Files.Count;
  if FileCount = 0 then Exit;
 
  OleCheck(SHGetMalloc(Malloc));
  OleCheck(SHGetDesktopFolder(Root));
  p := AllocMem(SizeOf(PItemIDList) * FileCount);
  try
    for i := 0 to FileCount - 1 do
      try
        if not (DirectoryExists(Files[i]) or FileExists(Files[i])) then Continue;
OleCheck(Root.ParseDisplayName(GetActiveWindow,nil,PWideChar(WideString(Files[i])),chEaten,p^[i],dwAttributes));
      except
      end;
    OleCheck(Root.GetUIObjectOf(GetActiveWindow,FileCount,p^[0],IDataObject,nil,Pointer(Result)));
  finally
    for i := 0 to FileCount - 1 do
    begin
      if p^[i] <> nil then Malloc.Free(p^[i]);
    end;
    FreeMem(p);
  end;
end;
 
procedure ShowFileProperties(Files: TStrings; aWnd: HWND);
type
  PArrayOfPItemIDList = ^TArrayOfPItemIDList;
  TArrayOfPItemIDList = array[0..0] of PItemIDList;
var
  Data: IDataObject;
begin
  if Files.Count = 0 then Exit;
  Data := GetFileListDataObject(Files);
  SHMultiFileProperties(Data, 0);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
 ShowFileProperties(Memo1.Lines, 0);
end;

<font color="red">źródło: Swiss Delphi Center</font>

Pozostało 580 znaków

2006-07-25 10:34
Ad
0

THX, ale w sekcji uses jest ActiveX.
Czy to będzie działać na komputerze bez zainstalowanego jakiegoś ActiveX'a?


Pozostało 580 znaków

2006-07-25 11:00
Opi
0
Opi napisał(a)

Przykład poprawnie funkcjonuje dla Windows 2000 i nowszym

Wymagany plik to: shell32.dll Powinno bez problemu uruchomić się (ActiveX jest ładowany do skompilowanego pliku EXE - twojego programu).

Pozostało 580 znaków

2006-07-25 11:02
Ad
0

:-) OK


Pozostało 580 znaków

2006-07-25 16:22
0

Właściwie to ActiveX to tylko nazwa modułu importowego zawierającego "definicje" (z braku lepszego słowa ;) ) funkcji znajdujących się w DLLkach Windowsa, które to funkcje mają zastosowanie głównie przy obsłudze kontrolek ActiveX i obiektów COM. Sam moduł to nie kontrolka ActiveX tylko zwykły moduł pascalowy, kwiatków nie będzie (no chyba, że w DLLkach Windowsa nie będą eksportowane funkcje, które ten moduł importuje, ale w to jakoś nie bardzo wierzę :) ).


Mam nadzieję, że pomogłem :)

Łukasz Brodny

Pozostało 580 znaków

2006-07-25 22:51
0

Można też tak (dla pojedynczego pliku):

uses ShellApi;
 
//...
 
procedure ShowProps(FileName: String);
var
  sei : SHELLEXECUTEINFO;
begin
  FillChar(sei, SizeOf(sei), 0);
  sei.cbSize := SizeOf(sei);
  sei.fMask := SEE_MASK_INVOKEIDLIST;
  sei.lpVerb := 'properties';
  sei.lpFile := PChar(FileName);
  ShellExecuteEx(@sei);
end;

M.O.R.R.I.S.: Mechanical Obedient Replicant Responsible for Infiltration and Sabotage
morris#rarlab*com

Pozostało 580 znaków

Odpowiedz
Liczba odpowiedzi na stronę

1 użytkowników online, w tym zalogowanych: 0, gości: 1, botów: 0