lista procedur

mam problem, bo nie wiem jak zrobić listę z dostępnymi w DLL-u procedurami
pomocy !!!

Było kiedyś takie pytanie:
http://4programmers.net/Forum/viewtopic.php?id=29665

Kod dostałem na maila od Pawła Knapka - pozwolę sobie go tu zamieścić:
-----------TNIJ-------------

uses
  ImageHlp;

procedure ListDLLExports(const FileName: string; List: TStrings);
type
  TDWordArray = array [0..$FFFFF] of DWORD;
var
  imageinfo: LoadedImage;
  pExportDirectory: PImageExportDirectory;
  dirsize: Cardinal;
  pDummy: PImageSectionHeader;
  i: Cardinal;
  pNameRVAs: ^TDWordArray;
  Name: string;
begin
  List.Clear;
  if MapAndLoad(PChar(FileName), nil, @imageinfo, True, True) 
then
  begin
    try
      pExportDirectory := ImageDirectoryEntryToData
(imageinfo.MappedAddress,
        False, IMAGE_DIRECTORY_ENTRY_EXPORT, dirsize);
      if (pExportDirectory <> nil) then
      begin
        pNameRVAs := ImageRvaToVa(imageinfo.FileHeader,
imageinfo.MappedAddress,
          DWORD(pExportDirectory^.AddressOfNames), pDummy);
        for i := 0 to pExportDirectory^.NumberOfNames - 1 do
        begin
          Name := PChar(ImageRvaToVa(imageinfo.FileHeader,
imageinfo.MappedAddress,
            pNameRVAs^[i], pDummy));
          List.Add(Name);
        end;
      end;
    finally
      UnMapAndLoad(@imageinfo);
    end;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  List: TStrings;
  i: Integer;
  s: string;
begin
  List := TStringList.Create;
  try
    ListDLLExports('C:\WINDOWS\SYSTEM32\browseui.dll', 
List); //Ścieżka do pliku dll
    ShowMessage(IntToStr(list.Count) + ' funkcji w pliku dll');
    s := 'Lista Funkcji:';
    for i := 0 to List.Count - 1 do
      s := s + #13#10 + List[i];
    ShowMessage(S);
  finally
    List.Free
  end;
end;

----------TNIJ------------

działa ale nie zawsze, w niektórych przypadkach wyskakuje błąd w linijce:
....
Name := PChar(ImageRvaToVa(imageinfo.FileHeader, imageinfo.MappedAddress, pNameRVAs^[i], pDummy));
....

błąd ... access violation at addres ... inmodule .... Read at ...