Pobieranie danych z zewnętrznej aplikacji przez uchwyty

Witajcie,

jakoś nigdy nie miałem potrzeby łączenia się z zewnętrzną aplikacją aby pobierać z niej dane w sposób inny niż jakieś api czy system importu / eksportu. Niestety przydusiło mnie i potrzebuję pobrać dane z okienka edit, przeliczyć a następnie wynik wpisać w innym okienku edit tej samej formy.

Aby nie rzucać się na głęboką wodę, utworzyłem mikro projekt na którym jest kilka komponentów (edit, button, memo, listbox) oraz drugi projekt w którym łapię uchwyty do tych komponentów. Nie sprawia to dużego problemu ale jest oczywiście pewne ale.

Oczywiście, ideałem byłoby aby numer uchwytu był stały, niestety tak dobrze nie jest. Dlatego muszę znaleźć jakiś sposób aby "dobierać" się do interesującego mnie pola za każdym razem po uruchomieniu programów.

Jak pisałem, bez problemu odczytuję numer uchwytu, jego klasę oraz wartość jaka się w nim znajduje (jeśli istnieje). Nie potrafię jednak odczytać jakiejś jego unikalnej nazwy, id czy cokolwiek niezmiennego.

Czy znacie jakiś sposób odczytu tych danych?

Dla potomnych, czytam uchwyty takim prostym programikiem:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics, Vcl.Controls, Vcl.Forms,
  Vcl.Dialogs, Vcl.StdCtrls, Vcl.ExtCtrls;

type
  TForm1 = class(TForm)
    Button1: TButton;
    ListBox1: TListBox;
    Edit1: TEdit;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure Edit1Change(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

function EnumChildProc(AHandle: THandle; AItems: TStrings): BOOL; stdcall;
var
  bufor: array[0..255] of Char;
  caption: array[0..255] of Char;
begin
  Result := True;
  GetClassName(AHandle, bufor, SizeOf(bufor) - 1);
  SendMessage(AHandle, WM_GETTEXT, 256, Integer(@caption));

  AItems.Add(Format('Handle: %d, Class: %s, Text: %s', [AHandle, bufor, caption]));
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  uchwyt: THandle;
  aplikacja: PChar;
begin
  aplikacja := PChar(Edit1.Text); // nazwa aplikacji z belki górnej
  uchwyt := FindWindow(nil, aplikacja);
  ListBox1.Clear;
  EnumChildWindows(uchwyt, @EnumChildProc, Integer(ListBox1.Items));
end;

procedure TForm1.Edit1Change(Sender: TObject);
begin
  if Edit1.Text <> '' then
    Button1.Enabled := True
  else
    Button1.Enabled := False;
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  Button1.Enabled := False;
end;

end.

Hej. Spojrzałem na chwilę co na Forum więc wracam z zaświatów :) Nie mam teraz dostępu do kompilatora. No ale enumerujesz kontrolki. Zatem jeśli program docelowy nawet "obcy" a nie jakiś Twój testowy w momencie odczytu zawartości okna ma pożądaną kontrolkę widoczną. A zawartość okna jest zawsze taka sama i jego układ. To nie musisz mieć nic unikalnego. Enumerując kontrolki będzie ona któraś z kolei, a zatem sprawdzasz sobie klasy i zwiększasz jakąś zmienną pomocniczą o jeden i na przykład szóste wystąpienie pola edycyjnego to właśnie spodziewana kontrolka.

Można jeszcze wyrażeniem regularnym wedle jakiegoś wzorca sprawdzać spodziewaną zawartość jeśli jest ona z przedziału jakiegoś formatu / znaków czy liczb albo długości. Dlatego nie bardzo rozumiem potrzeby unikalnej cechy kontrolki. Po to właśnie jest taka procedura do enumerowania kontrolek. Można zawsze też sprawdzać rodzica kontrolki czy jest to jakaś klasa albo właśnie kolejność kontrolki wobec innych kontrolek w oknie. Mam nadzieję że pomogłem. Bo jeżeli nie zrozumiałem Twojej idei to doprecyzuj. Ja na tę chwile kod na oko widzę jako poprawny i przy odpowiednim zastosowaniu nie ma potrzeby komplikacji problemu. A uchwyty zawsze kontrolek są nieco inne co każde uruchomienie aplikacji.

Oj chyba bardzo pomogłeś, odpowiednia kolejność występowania kontrolki całkowicie mi wystarczy (pod warunkiem że tak będzie - sprawdzę to ale myślę że masz w 100% rację). Co do zawartości to niestety, na formie (dokumentu sprzedaży) jest kilkanaście kontrolek o podobnej zawartości i ten sposób odpada.

Jeszcze raz dzięki za pomoc.

Jeżeli tamta aplikacja była napisana w Delphi to kiedyś w jednym ze swoich programów do pobrania nazwy używałem takiego kodu:

// Get Pointer to TWinControl in another process
function GetWinControl(Wnd: HWND; out ProcessId: THandle): Pointer;
var
  WindowAtomString: String;
  WindowAtom: ATOM;
begin
  GetWindowThreadProcessId(Wnd, @ProcessId);

  // This is atom for remote process (See controls.pas for details on this)
  WindowAtomString := Format('Delphi%.8X',[ProcessID]);
  WindowAtom := GlobalFindAtom(PChar(WindowAtomString));

  Result := Pointer(GetProp(Wnd, MakeIntAtom(WindowAtom)));
end;

function GetWinControlName(Wnd: HWND): WideString;
var
  ProcessID: THandle;
  ObjSelf: Pointer;
  Buf: Pointer;
  {$IF CompilerVersion >= 22} //Delphi XE
  bytes: NativeUInt;
  {$ELSE}
  bytes: Cardinal;
  {$IFEND}
  destProcess: THandle;
begin
  ObjSelf := GetWinControl(Wnd, ProcessId);

  destProcess := OpenProcess(PROCESS_VM_READ, TRUE, ProcessId);
  GetMem(Buf, 256);
  try
    if ReadProcessMemory(destProcess, Pointer(Cardinal(ObjSelf) + 8), Buf, 4, bytes) then
    begin
      ReadProcessMemory(destProcess, Pointer(Cardinal(Buf^)), Buf, 256, bytes);
    if IsWindowUnicode(Wnd) then
      Result := PWideChar(Buf)
    else
      Result:= WideString(PAnsiChar(Buf));
    end;
  finally
    FreeMem(Buf);
    CloseHandle(destProcess);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  //w Edit1 jest uchwyt (jako hex) a dostaje sie nazwę
  Edit1.Text:= GetWinControlName(StrToInt('$' + Edit1.Text));
end;

Użyj SpyXX - taka prosta aplikacja tam masz taki sprytny Ctr+F, którym możesz wskazać dany obiekt. Jak chwyci konkretny edit to spokojnie wydziergasz to w delphi. Jak nie chwyci ... to znaczy, że program był pisany np w Javie i wtedy handla będziesz miał do całej aplikacji bez podziału na poszczególne elementy ... wszystko zależy od tego jak zewnętrzna aplikacja była napisana.