Zamiana liczby z systemu addywnego na system arabski

Prosta funcja konwertująca z systemu rzymskiego na arabski może wyglądać np. tak:

function RzNaAr(Liczba: string): Word; 
const 
  I = 1; 
  V = 5; 
  X = 10; 
  L = 50; 
  C = 100; 
  D = 500; 
  M = 1000; 
var 
  Najw, j, Cyfra, Suma: Word; 
begin 
  Suma := 0; 
  Najw := 0; 
  for j := Length(Liczba) downto 1 do 
  begin 
    case UpCase(Liczba[j]) of 
      'I': Cyfra := I; 
      'V': Cyfra := V; 
      'X': Cyfra := X; 
      'L': Cyfra := L; 
      'C': Cyfra := C; 
      'D': Cyfra := D; 
      'M': Cyfra := M; 
    end; 
    if Cyfra >= Najw then 
    begin 
      Najw := Cyfra; 
      Suma := Suma + Najw; 
    end 
    else 
      Suma := Suma - Cyfra; 
    end; 
  Result := Suma; 
end; 

Można ją troszkę przerobić, żeby była wygodniejsza w modyfikacji dla każdego systemu addywnego.

function AddNaAr(Liczba: string): Word;
type TCyfra = record
  Sym{bol}: Char;
  Wart{osc}: Word;
  end;
const
  Tab: array [0..6] of TCyfra = (
    (Sym:'I'; Wart: 1),
    (Sym:'V'; Wart: 5),
    (Sym:'X'; Wart: 10),
    (Sym:'L'; Wart: 50),
    (Sym:'C'; Wart: 100),
    (Sym:'D'; Wart: 500),
    (Sym:'M'; Wart: 1000)
    );
var
  Najw, i, j, Cyfra, Suma: Word;
begin
  Suma := 0;
  Najw := 0;
  for j := Length(Liczba) downto 1 do
  begin
    i := 0;
    while Tab[i].Sym <> UpCase(Liczba[j]) do
      Inc(i);
    Cyfra := Tab[i].Wart;
    if Cyfra >= Najw then
    begin
      Najw := Cyfra;
      Suma := Suma + Najw;
    end
    else
      Suma := Suma - Cyfra;
  end;
  Result := Suma;
end;